mb/system76/kbl-u: Fix compiling

Restore the acpi/ directory, and fix dsdt.asl and devicetree.cb to build
after the merge.

Change-Id: I9b3f22db7b61e45523a0ecd022d4ba3eb117c329

src/mainboard/system76/kbl-u/acpi/ac.asl

@@ -0,0 +1,22 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+Device (AC)
+{
+	Name (_HID, "ACPI0003" /* Power Source Device */)  // _HID: Hardware ID
+	Name (_PCL, Package (0x01)  // _PCL: Power Consumer List
+	{
+		_SB
+	})
+
+	Name (ACFG, One)
+
+	Method (_PSR, 0, NotSerialized)  // _PSR: Power Source
+	{
+		Return (ACFG)
+	}
+
+	Method (_STA, 0, NotSerialized)  // _STA: Status
+	{
+		Return (0x0F)
+	}
+}

src/mainboard/system76/kbl-u/acpi/battery.asl

@@ -0,0 +1,170 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+Device (BAT0)
+{
+	Name (_HID, EisaId ("PNP0C0A") /* Control Method Battery */)  // _HID: Hardware ID
+	Name (_UID, Zero)  // _UID: Unique ID
+	Name (_PCL, Package (0x01)  // _PCL: Power Consumer List
+	{
+		_SB
+	})
+	Name (BFCC, Zero)
+	Method (_STA, 0, NotSerialized)  // _STA: Status
+	{
+		If (^^PCI0.LPCB.EC0.ECOK)
+		{
+			If (^^PCI0.LPCB.EC0.BAT0)
+			{
+				Return (0x1F)
+			}
+			Else
+			{
+				Return (0x0F)
+			}
+		}
+		Else
+		{
+			Return (0x0F)
+		}
+	}
+
+	Name (PBIF, Package (0x0D)
+	{
+		One,
+		0xFFFFFFFF,
+		0xFFFFFFFF,
+		One,
+		0x39D0,
+		Zero,
+		Zero,
+		0x40,
+		0x40,
+		"BAT",
+		"0001",
+		"LION",
+		"Notebook"
+	})
+	Method (IVBI, 0, NotSerialized)
+	{
+		PBIF [One] = 0xFFFFFFFF
+		PBIF [0x02] = 0xFFFFFFFF
+		PBIF [0x04] = 0xFFFFFFFF
+		PBIF [0x09] = " "
+		PBIF [0x0A] = " "
+		PBIF [0x0B] = " "
+		PBIF [0x0C] = " "
+		BFCC = Zero
+	}
+
+	Method (UPBI, 0, NotSerialized)
+	{
+		If (^^PCI0.LPCB.EC0.BAT0)
+		{
+			Local0 = (^^PCI0.LPCB.EC0.BDC0 & 0xFFFF)
+			PBIF [One] = Local0
+			Local0 = (^^PCI0.LPCB.EC0.BFC0 & 0xFFFF)
+			PBIF [0x02] = Local0
+			BFCC = Local0
+			Local0 = (^^PCI0.LPCB.EC0.BDV0 & 0xFFFF)
+			PBIF [0x04] = Local0
+			Local0 = (^^PCI0.LPCB.EC0.BCW0 & 0xFFFF)
+			PBIF [0x05] = Local0
+			Local0 = (^^PCI0.LPCB.EC0.BCL0 & 0xFFFF)
+			PBIF [0x06] = Local0
+			PBIF [0x09] = "BAT"
+			PBIF [0x0A] = "0001"
+			PBIF [0x0B] = "LION"
+			PBIF [0x0C] = "Notebook"
+		}
+		Else
+		{
+			IVBI ()
+		}
+	}
+
+	Method (_BIF, 0, NotSerialized)  // _BIF: Battery Information
+	{
+		If (^^PCI0.LPCB.EC0.ECOK)
+		{
+			UPBI ()
+		}
+		Else
+		{
+			IVBI ()
+		}
+
+		Return (PBIF) /* \_SB_.BAT0.PBIF */
+	}
+
+	Name (PBST, Package (0x04)
+	{
+		Zero,
+		0xFFFFFFFF,
+		0xFFFFFFFF,
+		0x3D90
+	})
+	Method (IVBS, 0, NotSerialized)
+	{
+		PBST [Zero] = Zero
+		PBST [One] = 0xFFFFFFFF
+		PBST [0x02] = 0xFFFFFFFF
+		PBST [0x03] = 0x2710
+	}
+
+	Method (UPBS, 0, NotSerialized)
+	{
+		If (^^PCI0.LPCB.EC0.BAT0)
+		{
+			Local0 = Zero
+			Local1 = Zero
+			If (^^AC.ACFG)
+			{
+				If (((^^PCI0.LPCB.EC0.BST0 & 0x02) == 0x02))
+				{
+					Local0 |= 0x02
+					Local1 = (^^PCI0.LPCB.EC0.BPR0 & 0xFFFF)
+				}
+			}
+			Else
+			{
+				Local0 |= One
+				Local1 = (^^PCI0.LPCB.EC0.BPR0 & 0xFFFF)
+			}
+
+			Local7 = (Local1 & 0x8000)
+			If ((Local7 == 0x8000))
+			{
+				Local1 ^= 0xFFFF
+			}
+
+			Local2 = (^^PCI0.LPCB.EC0.BRC0 & 0xFFFF)
+			Local3 = (^^PCI0.LPCB.EC0.BPV0 & 0xFFFF)
+			PBST [Zero] = Local0
+			PBST [One] = Local1
+			PBST [0x02] = Local2
+			PBST [0x03] = Local3
+			If ((BFCC != ^^PCI0.LPCB.EC0.BFC0))
+			{
+				Notify (BAT0, 0x81) // Information Change
+			}
+		}
+		Else
+		{
+			IVBS ()
+		}
+	}
+
+	Method (_BST, 0, NotSerialized)  // _BST: Battery Status
+	{
+		If (^^PCI0.LPCB.EC0.ECOK)
+		{
+			UPBS ()
+		}
+		Else
+		{
+			IVBS ()
+		}
+
+		Return (PBST) /* \_SB_.BAT0.PBST */
+	}
+}

src/mainboard/system76/kbl-u/acpi/buttons.asl

@@ -0,0 +1,13 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+Device (PWRB)
+{
+	Name (_HID, EisaId ("PNP0C0C"))
+	Name (_PRW, Package () { 0x13 /* GPP_C19 */, 3 })
+}
+
+Device (SLPB)
+{
+	Name (_HID, EisaId ("PNP0C0E"))
+	Name (_PRW, Package () { 0x13 /* GPP_C19 */, 3 })
+}

src/mainboard/system76/kbl-u/acpi/ec.asl

@@ -0,0 +1,222 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+Device (EC0)
+{
+	Name (_HID, EisaId ("PNP0C09") /* Embedded Controller Device */)  // _HID: Hardware ID
+	Name (_GPE, 0x50 /* GPP_E16 */)  // _GPE: General Purpose Events
+	Name (_CRS, ResourceTemplate ()  // _CRS: Current Resource Settings
+	{
+		IO (Decode16,
+			0x0062,             // Range Minimum
+			0x0062,             // Range Maximum
+			0x00,               // Alignment
+			0x01,               // Length
+			)
+		IO (Decode16,
+			0x0066,             // Range Minimum
+			0x0066,             // Range Maximum
+			0x00,               // Alignment
+			0x01,               // Length
+			)
+	})
+
+	#include "acpi/ec_ram.asl"
+
+	Name (ECOK, Zero)
+	Method (_REG, 2, Serialized)  // _REG: Region Availability
+	{
+		Debug = Concatenate("EC: _REG", Concatenate(ToHexString(Arg0), Concatenate(" ", ToHexString(Arg1))))
+		If (((Arg0 == 0x03) && (Arg1 == One))) {
+			// Enable hardware touchpad lock, airplane mode, and keyboard backlight keys
+			ECOS = 1
+
+			// Enable software display brightness keys
+			WINF = 1
+
+			// Set current AC state
+			^^^^AC.ACFG = ADP
+			// Update battery information and status
+			^^^^BAT0.UPBI()
+			^^^^BAT0.UPBS()
+
+			PNOT ()
+
+			// EC is now available
+			ECOK = Arg1
+
+			// Reset System76 Device
+			^^^^S76D.RSET()
+		}
+	}
+
+	Method (PTS, 1, Serialized) {
+		Debug = Concatenate("EC: PTS: ", ToHexString(Arg0))
+		If (ECOK) {
+			// Clear wake cause
+			WFNO = Zero
+		}
+	}
+
+	Method (WAK, 1, Serialized) {
+		Debug = Concatenate("EC: WAK: ", ToHexString(Arg0))
+		If (ECOK) {
+			// Set current AC state
+			^^^^AC.ACFG = ADP
+
+			// Update battery information and status
+			^^^^BAT0.UPBI()
+			^^^^BAT0.UPBS()
+
+			// Notify of changes
+			Notify(^^^^AC, Zero)
+			Notify(^^^^BAT0, Zero)
+
+			Sleep (1000)
+
+			// Reset System76 Device
+			^^^^S76D.RSET()
+		}
+	}
+
+	Method (_Q0A, 0, NotSerialized) // Touchpad Toggle
+	{
+		Debug = "EC: Touchpad Toggle"
+	}
+
+	Method (_Q0B, 0, NotSerialized) // Screen Toggle
+	{
+		Debug = "EC: Screen Toggle"
+	}
+
+	Method (_Q0C, 0, NotSerialized)  // Mute
+	{
+		Debug = "EC: Mute"
+	}
+
+	Method (_Q0D, 0, NotSerialized) // Keyboard Backlight
+	{
+		Debug = "EC: Keyboard Backlight"
+	}
+
+	Method (_Q0E, 0, NotSerialized) // Volume Down
+	{
+		Debug = "EC: Volume Down"
+	}
+
+	Method (_Q0F, 0, NotSerialized) // Volume Up
+	{
+		Debug = "EC: Volume Up"
+	}
+
+	Method (_Q10, 0, NotSerialized) // Switch Video Mode
+	{
+		Debug = "EC: Switch Video Mode"
+	}
+
+	Method (_Q11, 0, NotSerialized) // Brightness Down
+	{
+		Debug = "EC: Brightness Down"
+		if (^^^^HIDD.HRDY) {
+			^^^^HIDD.HPEM (20)
+		}
+	}
+
+	Method (_Q12, 0, NotSerialized) // Brightness Up
+	{
+		Debug = "EC: Brightness Up"
+		if (^^^^HIDD.HRDY) {
+			^^^^HIDD.HPEM (19)
+		}
+	}
+
+	Method (_Q13, 0, NotSerialized) // Camera Toggle
+	{
+		Debug = "EC: Camera Toggle"
+	}
+
+	Method (_Q14, 0, NotSerialized) // Airplane Mode
+	{
+		Debug = "EC: Airplane Mode"
+		if (^^^^HIDD.HRDY) {
+			^^^^HIDD.HPEM (8)
+		}
+		// TODO: hardware airplane mode
+	}
+
+	Method (_Q15, 0, NotSerialized) // Suspend Button
+	{
+		Debug = "EC: Suspend Button"
+		Notify (SLPB, 0x80)
+	}
+
+	Method (_Q16, 0, NotSerialized) // AC Detect
+	{
+		Debug = "EC: AC Detect"
+		^^^^AC.ACFG = ADP
+		Notify (AC, 0x80) // Status Change
+		Sleep (0x01F4)
+		If (BAT0)
+		{
+			Notify (^^^^BAT0, 0x81) // Information Change
+			Sleep (0x32)
+			Notify (^^^^BAT0, 0x80) // Status Change
+			Sleep (0x32)
+		}
+	}
+
+	Method (_Q17, 0, NotSerialized)  // BAT0 Update
+	{
+		Debug = "EC: BAT0 Update (17)"
+		Notify (^^^^BAT0, 0x81) // Information Change
+	}
+
+	Method (_Q19, 0, NotSerialized)  // BAT0 Update
+	{
+		Debug = "EC: BAT0 Update (19)"
+		Notify (^^^^BAT0, 0x81) // Information Change
+	}
+
+	Method (_Q1B, 0, NotSerialized) // Lid Close
+	{
+		Debug = "EC: Lid Close"
+		Notify (LID0, 0x80)
+	}
+
+	Method (_Q1C, 0, NotSerialized) // Thermal Trip
+	{
+		Debug = "EC: Thermal Trip"
+		/* TODO
+		Notify (\_TZ.TZ0, 0x81) // Thermal Trip Point Change
+		Notify (\_TZ.TZ0, 0x80) // Thermal Status Change
+		*/
+	}
+
+	Method (_Q1D, 0, NotSerialized) // Power Button
+	{
+		Debug = "EC: Power Button"
+		Notify (PWRB, 0x80)
+	}
+
+	Method (_Q50, 0, NotSerialized) // Other Events
+	{
+		Local0 = OEM4
+		If (Local0 == 0x8A) {
+			Debug = "EC: White Keyboard Backlight"
+			Notify (^^^^S76D, 0x80)
+		} ElseIf (Local0 == 0x9F) {
+			Debug = "EC: Color Keyboard Toggle"
+			Notify (^^^^S76D, 0x81)
+		} ElseIf (Local0 == 0x81) {
+			Debug = "EC: Color Keyboard Down"
+			Notify (^^^^S76D, 0x82)
+		} ElseIf (Local0 == 0x82) {
+			Debug = "EC: Color Keyboard Up"
+			Notify (^^^^S76D, 0x83)
+		} ElseIf (Local0 == 0x80) {
+			Debug = "EC: Color Keyboard Color Change"
+			Notify (^^^^S76D, 0x84)
+		} Else {
+			Debug = Concatenate("EC: Other: ", ToHexString(Local0))
+		}
+	}
+}

src/mainboard/system76/kbl-u/acpi/ec_ram.asl

@@ -0,0 +1,172 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+OperationRegion (ERAM, EmbeddedControl, Zero, 0xFF)
+Field (ERAM, ByteAcc, Lock, Preserve)
+{
+	NMSG,   8,
+	SLED,   4,
+	Offset (0x02),
+	MODE,   1,
+	FAN0,   1,
+	TME0,   1,
+	TME1,   1,
+	FAN1,   1,
+		,   2,
+	Offset (0x03),
+	LSTE,   1,
+	LSW0,   1,
+	LWKE,   1,
+	WAKF,   1,
+		,   2,
+	PWKE,   1,
+	MWKE,   1,
+	AC0,    8,
+	PSV,    8,
+	CRT,    8,
+	TMP,    8,
+	AC1,    8,
+	BBST,   8,
+	Offset (0x0B),
+	Offset (0x0C),
+	Offset (0x0D),
+	Offset (0x0E),
+	SLPT,   8,
+	SWEJ,   1,
+	SWCH,   1,
+	Offset (0x10),
+	ADP,    1,
+	AFLT,   1,
+	BAT0,   1,
+	BAT1,   1,
+		,   3,
+	PWOF,   1,
+	WFNO,   8,
+	BPU0,   32,
+	BDC0,   32,
+	BFC0,   32,
+	BTC0,   32,
+	BDV0,   32,
+	BST0,   32,
+	BPR0,   32,
+	BRC0,   32,
+	BPV0,   32,
+	BTP0,   16,
+	BRS0,   16,
+	BCW0,   32,
+	BCL0,   32,
+	BCG0,   32,
+	BG20,   32,
+	BMO0,   64,
+	BIF0,   64,
+	BSN0,   32,
+	BTY0,   64,
+	Offset (0x67),
+	Offset (0x68),
+	ECOS,   8,
+	LNXD,   8,
+	ECPS,   8,
+	Offset (0x6C),
+	BTMP,   16,
+	EVTN,   8,
+	Offset (0x72),
+	PRCL,   8,
+	PRC0,   8,
+	PRC1,   8,
+	PRCM,   8,
+	PRIN,   8,
+	PSTE,   8,
+	PCAD,   8,
+	PEWL,   8,
+	PWRL,   8,
+	PECD,   8,
+	PEHI,   8,
+	PECI,   8,
+	PEPL,   8,
+	PEPM,   8,
+	PWFC,   8,
+	PECC,   8,
+	PDT0,   8,
+	PDT1,   8,
+	PDT2,   8,
+	PDT3,   8,
+	PRFC,   8,
+	PRS0,   8,
+	PRS1,   8,
+	PRS2,   8,
+	PRS3,   8,
+	PRS4,   8,
+	PRCS,   8,
+	PEC0,   8,
+	PEC1,   8,
+	PEC2,   8,
+	PEC3,   8,
+	CMDR,   8,
+	CVRT,   8,
+	GTVR,   8,
+	FANT,   8,
+	SKNT,   8,
+	AMBT,   8,
+	MCRT,   8,
+	DIM0,   8,
+	DIM1,   8,
+	PMAX,   8,
+	PPDT,   8,
+	PECH,   8,
+	PMDT,   8,
+	TSD0,   8,
+	TSD1,   8,
+	TSD2,   8,
+	TSD3,   8,
+	CPUP,   16,
+	MCHP,   16,
+	SYSP,   16,
+	CPAP,   16,
+	MCAP,   16,
+	SYAP,   16,
+	CFSP,   16,
+	CPUE,   16,
+	Offset (0xC6),
+	Offset (0xC7),
+	VGAT,   8,
+	OEM1,   8,
+	OEM2,   8,
+	OEM3,   16,
+	OEM4,   8,
+	Offset (0xCE),
+	DUT1,   8,
+	DUT2,   8,
+	RPM1,   16,
+	RPM2,   16,
+	RPM4,   16,
+	Offset (0xD7),
+	DTHL,   8,
+	DTBP,   8,
+	AIRP,   8,
+	WINF,   8,
+	RINF,   8,
+	Offset (0xDD),
+	INF2,   8,
+	MUTE,   1,
+	Offset (0xE0),
+	RPM3,   16,
+	ECKS,   8,
+	Offset (0xE4),
+		,   4,
+	XTUF,   1,
+	EP12,   1,
+	Offset (0xE5),
+	INF3,   8,
+	Offset (0xE7),
+	GFOF,   8,
+	Offset (0xF0),
+	PL1T,   16,
+	PL2T,   16,
+	TAUT,   8,
+	Offset (0xF8),
+	FCMD,   8,
+	FDAT,   8,
+	FBUF,   8,
+	FBF1,   8,
+	FBF2,   8,
+	FBF3,   8
+}

src/mainboard/system76/kbl-u/acpi/gpe.asl

@@ -0,0 +1,11 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+// GPP_C19 SCI
+Method (_L13, 0, Serialized) {
+	Debug = Concatenate("GPE _L13: ", ToHexString(\_SB.PCI0.LPCB.EC0.WFNO))
+	If (\_SB.PCI0.LPCB.EC0.ECOK) {
+		If (\_SB.PCI0.LPCB.EC0.WFNO == 1) {
+			Notify(\_SB.LID0, 0x80)
+		}
+	}
+}

src/mainboard/system76/kbl-u/acpi/hid.asl

@@ -0,0 +1,50 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+Device (HIDD)
+{
+	Name (_HID, "INT33D5")
+	Name (HBSY, Zero)
+	Name (HIDX, Zero)
+	Name (HRDY, Zero)
+
+	Method (HDEM, 0, Serialized)
+	{
+		HBSY = Zero
+		Return (HIDX)
+	}
+
+	Method (HDMM, 0, Serialized)
+	{
+		Return (Zero)
+	}
+
+	Method (HDSM, 1, Serialized)
+	{
+		HRDY = Arg0
+	}
+
+	Method (HPEM, 1, Serialized)
+	{
+		HBSY = One
+		HIDX = Arg0
+
+		Notify (HIDD, 0xC0)
+		Local0 = Zero
+		While (((Local0 < 0xFA) && HBSY))
+		{
+			Sleep (0x04)
+			Local0++
+		}
+
+		If ((HBSY == One))
+		{
+			HBSY = Zero
+			HIDX = Zero
+			Return (One)
+		}
+		Else
+		{
+			Return (Zero)
+		}
+	}
+}

src/mainboard/system76/kbl-u/acpi/lid.asl

@@ -0,0 +1,23 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+Device (LID0)
+{
+	Name (_HID, EisaId ("PNP0C0D"))
+	Name (_PRW, Package () { 0x13 /* GPP_C19 */, 3 })
+
+	Method (_LID, 0, NotSerialized) {
+		DEBUG = "LID: _LID"
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			Return (^^PCI0.LPCB.EC0.LSTE)
+		} Else {
+			Return (One)
+		}
+	}
+
+	Method (_PSW, 1, NotSerialized) {
+		DEBUG = Concatenate("LID: _PSW: ", ToHexString(Arg0))
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			^^PCI0.LPCB.EC0.LWKE = Arg0
+		}
+	}
+}

src/mainboard/system76/kbl-u/acpi/mainboard.asl

@@ -0,0 +1,15 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+Scope (\_SB) {
+	#include "ac.asl"
+	#include "battery.asl"
+	#include "buttons.asl"
+	#include "hid.asl"
+	#include "lid.asl"
+	#include "s76.asl"
+	#include "sleep.asl"
+}
+
+Scope (_GPE) {
+	#include "gpe.asl"
+}

src/mainboard/system76/kbl-u/acpi/s76.asl

@@ -0,0 +1,84 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+// Notifications:
+//   0x80 - hardware backlight toggle
+//   0x81 - backlight toggle
+//   0x82 - backlight down
+//   0x83 - backlight up
+//   0x84 - backlight color change
+Device (S76D) {
+	Name (_HID, "17761776")
+	Name (_UID, 0)
+
+	Method (RSET, 0, Serialized) {
+		Debug = "S76D: RSET"
+		SAPL(0)
+		SKBL(0)
+	}
+
+	Method (INIT, 0, Serialized) {
+		Debug = "S76D: INIT"
+		RSET()
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			// Set flags to use software control
+			^^PCI0.LPCB.EC0.ECOS = 2
+			Return (0)
+		} Else {
+			Return (1)
+		}
+	}
+
+	Method (FINI, 0, Serialized) {
+		Debug = "S76D: FINI"
+		RSET()
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			// Set flags to use hardware control
+			^^PCI0.LPCB.EC0.ECOS = 1
+			Return (0)
+		} Else {
+			Return (1)
+		}
+	}
+
+	// Get Airplane LED
+	Method (GAPL, 0, Serialized) {
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			If (^^PCI0.LPCB.EC0.AIRP & 0x40) {
+				Return (1)
+			}
+		}
+		Return (0)
+	}
+
+	// Set Airplane LED
+	Method (SAPL, 1, Serialized) {
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			If (Arg0) {
+				^^PCI0.LPCB.EC0.AIRP |= 0x40
+			} Else {
+				^^PCI0.LPCB.EC0.AIRP &= 0xBF
+			}
+		}
+	}
+
+	// Get KB LED
+	Method (GKBL, 0, Serialized) {
+		Local0 = 0
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			^^PCI0.LPCB.EC0.FDAT = One
+			^^PCI0.LPCB.EC0.FCMD = 0xCA
+			Local0 = ^^PCI0.LPCB.EC0.FBUF
+			^^PCI0.LPCB.EC0.FCMD = Zero
+		}
+		Return (Local0)
+	}
+
+	// Set KB Led
+	Method (SKBL, 1, Serialized) {
+		If (^^PCI0.LPCB.EC0.ECOK) {
+			^^PCI0.LPCB.EC0.FDAT = Zero
+			^^PCI0.LPCB.EC0.FBUF = Arg0
+			^^PCI0.LPCB.EC0.FCMD = 0xCA
+		}
+	}
+}

src/mainboard/system76/kbl-u/acpi/sleep.asl

@@ -0,0 +1,11 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+/* Method called from _PTS prior to enter sleep state */
+Method (MPTS, 1) {
+	\_SB.PCI0.LPCB.EC0.PTS (Arg0)
+}
+
+/* Method called from _WAK prior to wakeup */
+Method (MWAK, 1) {
+	\_SB.PCI0.LPCB.EC0.WAK (Arg0)
+}

src/mainboard/system76/kbl-u/acpi/superio.asl

@@ -0,0 +1,3 @@
+/* SPDX-License-Identifier: GPL-2.0-only */
+
+#include <drivers/pc80/pc/ps2_controller.asl>

src/mainboard/system76/kbl-u/devicetree.cb

@@ -22,16 +22,10 @@ chip soc/intel/skylake
 	register "gen3_dec" = "0x000c0081"
 	register "gen4_dec" = "0x00040069"
 
-	# Enable "Intel Speed Shift Technology"
-	register "speed_shift_enable" = "1"
-
 	# Disable DPTF
 	register "dptf_enable" = "0"
 
 	# FSP Configuration
-	register "ProbelessTrace" = "0"
-	register "EnableLan" = "0"
-	register "EnableSata" = "1"
 	register "SataSalpSupport" = "0"
 	register "SataMode" = "0"
 	register "SataPortsEnable[0]" = "1"
@@ -40,19 +34,11 @@ chip soc/intel/skylake
 	register "SataPortsDevSlp[0]" = "0"
 	register "SataPortsDevSlp[2]" = "0"
 	register "SataSpeedLimit" = "2"
-	register "EnableAzalia" = "1"
 	register "DspEnable" = "0"
 	register "IoBufferOwnership" = "0"
-	register "EnableTraceHub" = "0"
 	register "SsicPortEnable" = "0"
-	register "SmbusEnable" = "1"
-	register "Cio2Enable" = "0"
-	register "ScsEmmcEnabled" = "0"
 	register "ScsEmmcHs400Enabled" = "0"
-	register "ScsSdCardEnabled" = "0"
-	register "PttSwitch" = "0"
 	register "SkipExtGfxScan" = "1"
-	register "Device4Enable" = "1"
 	register "HeciEnabled" = "1"
 	register "SaGv" = "3"
 	register "serirq_mode" = "SERIRQ_CONTINUOUS"
@@ -60,16 +46,6 @@ chip soc/intel/skylake
 	register "PmConfigSlpS4MinAssert" = "1"        # 1s
 	register "PmConfigSlpSusMinAssert" = "3"    # 500ms
 	register "PmConfigSlpAMinAssert" = "3"        # 2s
-	register "PmTimerDisabled" = "0"
-
-	register "pirqa_routing" = "PCH_IRQ11"
-	register "pirqb_routing" = "PCH_IRQ10"
-	register "pirqc_routing" = "PCH_IRQ11"
-	register "pirqd_routing" = "PCH_IRQ11"
-	register "pirqe_routing" = "PCH_IRQ11"
-	register "pirqf_routing" = "PCH_IRQ11"
-	register "pirqg_routing" = "PCH_IRQ11"
-	register "pirqh_routing" = "PCH_IRQ11"
 
 	# Power limit
 	register "power_limits_config" = "{
@@ -166,6 +142,7 @@ chip soc/intel/skylake
 	device domain 0 on
 		device pci 00.0 on  end # Host Bridge
 		device pci 02.0 on  end # Integrated Graphics Device
+		device pci 04.0 on  end # SA thermal subsystem
 		device pci 14.0 on      # USB xHCI
 			# USB2
 			register "usb2_ports[0]" = "USB2_PORT_MID(OC_SKIP)"         # Type-A port right
@@ -183,6 +160,7 @@ chip soc/intel/skylake
 		end
 		device pci 14.1 off end # USB xDCI (OTG)
 		device pci 14.2 on  end # Thermal Subsystem
+		device pci 14.3 off end # Camera
 		device pci 16.0 off end # Management Engine Interface 1
 		device pci 16.1 off end # Management Engine Interface 2
 		device pci 16.2 off end # Management Engine IDE-R
@@ -234,6 +212,7 @@ chip soc/intel/skylake
 		device pci 1d.1 off end # PCI Express Port 10
 		device pci 1d.2 off end # PCI Express Port 11
 		device pci 1d.3 off end # PCI Express Port 12
+		device pci 1e.6 off end # SDXC
 		device pci 1f.0 on
 			chip drivers/pc80/tpm
 				device pnp 0c31.0 on end

src/mainboard/system76/kbl-u/dsdt.asl

@@ -10,26 +10,17 @@ DefinitionBlock(
 	0x20110725	// OEM revision
 )
 {
-	// Some generic macros
+	#include <soc/intel/common/block/acpi/acpi/platform.asl>
-	#include <soc/intel/skylake/acpi/platform.asl>
-
-	// global NVS and variables
 	#include <soc/intel/skylake/acpi/globalnvs.asl>
-
-	// CPU
 	#include <cpu/intel/common/acpi/cpu.asl>
 
-	Scope (\_SB) {
+	Device (\_SB.PCI0)
-		Device (PCI0)
+	{
-		{
+		#include <soc/intel/skylake/acpi/systemagent.asl>
-			#include <soc/intel/skylake/acpi/systemagent.asl>
+		#include <soc/intel/skylake/acpi/pch.asl>
-			#include <soc/intel/skylake/acpi/pch.asl>
-		}
 	}
 
-	// Chipset specific sleep states
 	#include <southbridge/intel/common/acpi/sleepstates.asl>
 
-	// Mainboard specific
 	#include "acpi/mainboard.asl"
 }