Files
system76-coreboot/src/arch/x86/thread_switch.S
Raul E Rangel 6a01ac2504 arch/x86/thread: Add #error when compiling for x86_64
The x86 thread code is all x86_32 specific. It needs to be updated to
work with 64 bit. For now just throw an error when compiling.

BUG=b:179699789
TEST=none

Suggested-by: Furquan Shaikh <furquan@google.com>
Signed-off-by: Raul E Rangel <rrangel@chromium.org>
Change-Id: I96187ad84bdec40c6883748afa41e217bc389b79
Reviewed-on: https://review.coreboot.org/c/coreboot/+/56571
Tested-by: build bot (Jenkins) <no-reply@coreboot.org>
Reviewed-by: Julius Werner <jwerner@chromium.org>
2021-07-29 09:12:24 +00:00

47 lines
962 B
ArmAsm

/* SPDX-License-Identifier: GPL-2.0-only */
#if ENV_X86_64
#error COOP_MULTITASKING does not currently support x86_64
#endif
.code32
.text
/*
* stack layout after pushad:
* +------------+
* | save stack | <-- esp + 0x28
* +------------+
* | new stack | <-- esp + 0x24
* +------------+
* | ret addr | <-- esp + 0x20
* +------------+
* | eax | <-- esp + 0x1c
* +------------+
* | ecx | <-- esp + 0x18
* +------------+
* | edx | <-- esp + 0x14
* +------------+
* | ebx | <-- esp + 0x10
* +------------+
* | orig esp | <-- esp + 0x0c
* +------------+
* | ebp | <-- esp + 0x08
* +------------+
* | esi | <-- esp + 0x04
* +------------+
* | edi | <-- esp + 0x00
* +------------+
*/
.globl switch_to_thread
switch_to_thread:
pusha
/* Save the current stack */
movl 0x28(%esp), %ebx
movl %esp, (%ebx)
/* Switch to the new stack. */
movl 0x24(%esp), %eax
movl %eax, %esp
popa
ret