sravan/system76-edk2
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity

MdePkg/BaseMemoryLibSse2: Remove .S files for IA32 and X64 arch

Browse Source 
.nasm file has been added for X86 arch. .S assembly code
is not required any more.
https://bugzilla.tianocore.org/show_bug.cgi?id=1594

Cc: Michael D Kinney <michael.d.kinney@intel.com>
Cc: Liming Gao <liming.gao@intel.com>
Contributed-under: TianoCore Contribution Agreement 1.1
Signed-off-by: Shenglei Zhang <shenglei.zhang@intel.com>
Reviewed-by: Liming Gao <liming.gao@intel.com>
This commit is contained in:
Shenglei Zhang
2019-03-07 09:10:26 +08:00
committed by Liming Gao
parent 42b7b15d27
commit 94cf7d235a
23 changed files with 0 additions and 1417 deletions
Download Patch File Download Diff File Expand all files Collapse all files

55
MdePkg/Library/BaseMemoryLibSse2/Ia32/CompareMem.S
View File

@@ -1,55 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# CompareMem.Asm
#
# Abstract:
#
# CompareMem function
#
# Notes:
#
# The following BaseMemoryLib instances contain the same copy of this file:
#
# BaseMemoryLibRepStr
# BaseMemoryLibMmx
# BaseMemoryLibSse2
# BaseMemoryLibOptDxe
# BaseMemoryLibOptPei
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemCompareMem)
#------------------------------------------------------------------------------
# INTN
# EFIAPI
# InternalMemCompareMem (
# IN CONST VOID *DestinationBuffer,
# IN CONST VOID *SourceBuffer,
# IN UINTN Length
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemCompareMem):
push %esi
push %edi
movl 12(%esp), %esi
movl 16(%esp), %edi
movl 20(%esp), %ecx
repe cmpsb
movzbl -1(%esi), %eax
movzbl -1(%edi), %edx
subl %edx, %eax
pop %edi
pop %esi
ret

85
MdePkg/Library/BaseMemoryLibSse2/Ia32/CopyMem.S
View File

@@ -1,85 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# CopyMem.asm
#
# Abstract:
#
# CopyMem function
#
# Notes:
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemCopyMem)
#------------------------------------------------------------------------------
# VOID *
# EFIAPI
# InternalMemCopyMem (
# IN VOID *Destination,
# IN VOID *Source,
# IN UINTN Count
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemCopyMem):
push %esi
push %edi
movl 16(%esp), %esi # esi <- Source
movl 12(%esp), %edi # edi <- Destination
movl 20(%esp), %edx # edx <- Count
leal -1(%esi,%edx,), %eax # eax <- End of Source
cmpl %edi, %esi
jae L0
cmpl %edi, %eax # Overlapped?
jae L_CopyBackward # Copy backward if overlapped
L0:
xorl %ecx, %ecx
subl %edi, %ecx
andl $15, %ecx # ecx + edi aligns on 16-byte boundary
jz L1
cmpl %edx, %ecx
cmova %edx, %ecx
subl %ecx, %edx # edx <- remaining bytes to copy
rep
movsb
L1:
movl %edx, %ecx
andl $15, %edx
shrl $4, %ecx # ecx <- # of DQwords to copy
jz L_CopyBytes
addl $-16, %esp
movdqu %xmm0, (%esp)
L2:
movdqu (%esi), %xmm0
movntdq %xmm0, (%edi)
addl $16, %esi
addl $16, %edi
loop L2
mfence
movdqu (%esp),%xmm0
addl $16, %esp # stack cleanup
jmp L_CopyBytes
L_CopyBackward:
movl %eax, %esi # esi <- Last byte in Source
leal -1(%edi,%edx,), %edi # edi <- Last byte in Destination
std
L_CopyBytes:
movl %edx, %ecx
rep
movsb
cld
movl 12(%esp), %eax # eax <- Destination as return value
pop %edi
pop %esi
ret

52
MdePkg/Library/BaseMemoryLibSse2/Ia32/ScanMem16.S
View File

@@ -1,52 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# ScanMem16.Asm
#
# Abstract:
#
# ScanMem16 function
#
# Notes:
#
# The following BaseMemoryLib instances contain the same copy of this file:
#
# BaseMemoryLibRepStr
# BaseMemoryLibMmx
# BaseMemoryLibSse2
# BaseMemoryLibOptDxe
# BaseMemoryLibOptPei
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemScanMem16)
#------------------------------------------------------------------------------
# CONST VOID *
# EFIAPI
# InternalMemScanMem16 (
# IN CONST VOID *Buffer,
# IN UINTN Length,
# IN UINT16 Value
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemScanMem16):
push %edi
movl 12(%esp), %ecx
movl 8(%esp), %edi
movl 16(%esp), %eax
repne scasw
leal -2(%edi), %eax
cmovnz %ecx, %eax
pop %edi
ret

52
MdePkg/Library/BaseMemoryLibSse2/Ia32/ScanMem32.S
View File

@@ -1,52 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# ScanMem32.Asm
#
# Abstract:
#
# ScanMem32 function
#
# Notes:
#
# The following BaseMemoryLib instances contain the same copy of this file:
#
# BaseMemoryLibRepStr
# BaseMemoryLibMmx
# BaseMemoryLibSse2
# BaseMemoryLibOptDxe
# BaseMemoryLibOptPei
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemScanMem32)
#------------------------------------------------------------------------------
# CONST VOID *
# EFIAPI
# InternalMemScanMem32 (
# IN CONST VOID *Buffer,
# IN UINTN Length,
# IN UINT32 Value
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemScanMem32):
push %edi
movl 12(%esp), %ecx
movl 8(%esp), %edi
movl 16(%esp), %eax
repne scasl
leal -4(%edi), %eax
cmovnz %ecx, %eax
pop %edi
ret

61
MdePkg/Library/BaseMemoryLibSse2/Ia32/ScanMem64.S
View File

@@ -1,61 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# ScanMem64.Asm
#
# Abstract:
#
# ScanMem64 function
#
# Notes:
#
# The following BaseMemoryLib instances contain the same copy of this file:
#
# BaseMemoryLibRepStr
# BaseMemoryLibMmx
# BaseMemoryLibSse2
# BaseMemoryLibOptDxe
# BaseMemoryLibOptPei
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemScanMem64)
#------------------------------------------------------------------------------
# CONST VOID *
# EFIAPI
# InternalMemScanMem64 (
# IN CONST VOID *Buffer,
# IN UINTN Length,
# IN UINT64 Value
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemScanMem64):
push %edi
movl 12(%esp), %ecx
movl 16(%esp), %eax
movl 20(%esp), %edx
movl 8(%esp), %edi
L0:
cmpl (%edi), %eax
leal 8(%edi), %edi
loopne L0
jne L1
cmpl -4(%edi), %edx
jecxz L1
jne L0
L1:
leal -8(%edi), %eax
cmovne %ecx, %eax
pop %edi
ret

52
MdePkg/Library/BaseMemoryLibSse2/Ia32/ScanMem8.S
View File

@@ -1,52 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# ScanMem8.Asm
#
# Abstract:
#
# ScanMem8 function
#
# Notes:
#
# The following BaseMemoryLib instances contain the same copy of this file:
#
# BaseMemoryLibRepStr
# BaseMemoryLibMmx
# BaseMemoryLibSse2
# BaseMemoryLibOptDxe
# BaseMemoryLibOptPei
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemScanMem8)
#------------------------------------------------------------------------------
# CONST VOID *
# EFIAPI
# InternalMemScanMem8 (
# IN CONST VOID *Buffer,
# IN UINTN Length,
# IN UINT8 Value
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemScanMem8):
push %edi
movl 12(%esp), %ecx
movl 8(%esp), %edi
movb 16(%esp), %al
repne scasb
leal -1(%edi), %eax
cmovnz %ecx, %eax
pop %edi
ret

76
MdePkg/Library/BaseMemoryLibSse2/Ia32/SetMem.S
View File

@@ -1,76 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# SetMem.asm
#
# Abstract:
#
# SetMem function
#
# Notes:
#
#------------------------------------------------------------------------------
#.MODEL flat,C
.xmm:
.code:
#------------------------------------------------------------------------------
# VOID *
# _mem_SetMem (
# IN VOID *Buffer,
# IN UINTN Count,
# IN UINT8 Value
# );
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemSetMem)
ASM_PFX(InternalMemSetMem):
push %edi
movl 12(%esp), %edx # edx <- Count
movl 8(%esp), %edi # edi <- Buffer
movb 16(%esp), %al # al <- Value
xorl %ecx, %ecx
subl %edi, %ecx
andl $15, %ecx # ecx + edi aligns on 16-byte boundary
jz L0
cmpl %edx, %ecx
cmova %edx, %ecx
subl %ecx, %edx
rep
stosb
L0:
movl %edx, %ecx
andl $15, %edx
shrl $4, %ecx # ecx <- # of DQwords to set
jz L_SetBytes
movb %al, %ah # ax <- Value | (Value << 8)
addl $-16, %esp
movdqu %xmm0, (%esp)
movd %eax, %xmm0
pshuflw $0, %xmm0, %xmm0
movlhps %xmm0, %xmm0
L1:
movntdq %xmm0, (%edi)
addl $16, %edi
loop L1
mfence
movdqu (%esp), %xmm0
addl $16, %esp # stack cleanup
L_SetBytes:
movl %edx, %ecx
rep
stosb
movl 8(%esp), %eax # eax <- Buffer as return value
pop %edi
ret

69
MdePkg/Library/BaseMemoryLibSse2/Ia32/SetMem16.S
View File

@@ -1,69 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# SetMem16.asm
#
# Abstract:
#
# SetMem16 function
#
# Notes:
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemSetMem16)
#------------------------------------------------------------------------------
# VOID *
# EFIAPI
# InternalMemSetMem16 (
# IN VOID *Buffer,
# IN UINTN Count,
# IN UINT16 Value
# )
#------------------------------------------------------------------------------
ASM_PFX(InternalMemSetMem16):
push %edi
movl 12(%esp), %edx
movl 8(%esp), %edi
xorl %ecx, %ecx
subl %edi, %ecx
andl $15, %ecx # ecx + edi aligns on 16-byte boundary
movl 16(%esp), %eax
jz L0
shrl %ecx
cmpl %edx, %ecx
cmova %edx, %ecx
subl %ecx, %edx
rep
stosw
L0:
movl %edx, %ecx
andl $7, %edx
shrl $3, %ecx
jz L_SetWords
movd %eax, %xmm0
pshuflw $0, %xmm0, %xmm0
movlhps %xmm0, %xmm0
L1:
movntdq %xmm0, (%edi)
addl $16, %edi
loop L1
mfence
L_SetWords:
movl %edx, %ecx
rep
stosw
movl 8(%esp), %eax
pop %edi
ret

68
MdePkg/Library/BaseMemoryLibSse2/Ia32/SetMem32.S
View File

@@ -1,68 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# SetMem32.asm
#
# Abstract:
#
# SetMem32 function
#
# Notes:
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemSetMem32)
#------------------------------------------------------------------------------
# VOID *
# EFIAPI
# InternalMemSetMem32 (
# IN VOID *Buffer,
# IN UINTN Count,
# IN UINT32 Value
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemSetMem32):
push %edi
movl 12(%esp), %edx
movl 8(%esp), %edi
xorl %ecx, %ecx
subl %edi, %ecx
andl $15, %ecx # ecx + edi aligns on 16-byte boundary
movl 16(%esp), %eax
jz L0
shrl $2, %ecx
cmpl %edx, %ecx
cmova %edx, %ecx
subl %ecx, %edx
rep
stosl
L0:
movl %edx, %ecx
andl $3, %edx
shrl $2, %ecx
jz L_SetDwords
movd %eax, %xmm0
pshufd $0, %xmm0, %xmm0
L1:
movntdq %xmm0, (%edi)
addl $16, %edi
loop L1
mfence
L_SetDwords:
movl %edx, %ecx
rep
stosl
movl 8(%esp), %eax
pop %edi
ret

58
MdePkg/Library/BaseMemoryLibSse2/Ia32/SetMem64.S
View File

@@ -1,58 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# SetMem64.S
#
# Abstract:
#
# SetMem64 function
#
# Notes:
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemSetMem64)
#------------------------------------------------------------------------------
# VOID *
# EFIAPI
# InternalMemSetMem64 (
# IN VOID *Buffer,
# IN UINTN Count,
# IN UINT64 Value
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemSetMem64):
movl 4(%esp), %eax
movl 8(%esp), %ecx
testb $8, %al
movl %eax, %edx
movq 0xc(%esp), %xmm0
jz L1
movq %xmm0, (%edx)
addl $8, %edx
decl %ecx
L1:
shrl %ecx
jz L_SetQwords
movlhps %xmm0, %xmm0
L2:
movntdq %xmm0, (%edx)
leal 16(%edx), %edx
loop L2
mfence
L_SetQwords:
jnc L3
movq %xmm0, (%edx)
L3:
ret

65
MdePkg/Library/BaseMemoryLibSse2/Ia32/ZeroMem.S
View File

@@ -1,65 +0,0 @@
#------------------------------------------------------------------------------
#
# Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
# This program and the accompanying materials
# are licensed and made available under the terms and conditions of the BSD License
# which accompanies this distribution. The full text of the license may be found at
# http://opensource.org/licenses/bsd-license.php.
#
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
#
# Module Name:
#
# ZeroMem.asm
#
# Abstract:
#
# ZeroMem function
#
# Notes:
#
#------------------------------------------------------------------------------
ASM_GLOBAL ASM_PFX(InternalMemZeroMem)
#------------------------------------------------------------------------------
# VOID *
# EFIAPI
# InternalMemZeroMem (
# IN VOID *Buffer,
# IN UINTN Count
# );
#------------------------------------------------------------------------------
ASM_PFX(InternalMemZeroMem):
push %edi
movl 8(%esp), %edi
movl 12(%esp), %edx
xorl %ecx, %ecx
subl %edi, %ecx
xorl %eax, %eax
andl $15, %ecx
jz L0
cmpl %edx, %ecx
cmova %edx, %ecx
subl %ecx, %edx
rep
stosb
L0:
movl %edx, %ecx
andl $15, %edx
shrl $4, %ecx
jz L_ZeroBytes
pxor %xmm0, %xmm0
L1:
movntdq %xmm0, (%edi)
addl $16, %edi
loop L1
mfence
L_ZeroBytes:
movl %edx, %ecx
rep
stosb
movl 8(%esp), %eax
pop %edi
ret