9344f09215
https://bugzilla.tianocore.org/show_bug.cgi?id=1373 Replace BSD 2-Clause License with BSD+Patent License. This change is based on the following emails: https://lists.01.org/pipermail/edk2-devel/2019-February/036260.html https://lists.01.org/pipermail/edk2-devel/2018-October/030385.html RFCs with detailed process for the license change: V3: https://lists.01.org/pipermail/edk2-devel/2019-March/038116.html V2: https://lists.01.org/pipermail/edk2-devel/2019-March/037669.html V1: https://lists.01.org/pipermail/edk2-devel/2019-March/037500.html Contributed-under: TianoCore Contribution Agreement 1.1 Signed-off-by: Michael D Kinney <michael.d.kinney@intel.com> Reviewed-by: Liming Gao <liming.gao@intel.com>
69 lines
2.1 KiB
NASM
69 lines
2.1 KiB
NASM
;------------------------------------------------------------------------------
|
|
;
|
|
; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>
|
|
; SPDX-License-Identifier: BSD-2-Clause-Patent
|
|
;
|
|
; Module Name:
|
|
;
|
|
; CopyMem.nasm
|
|
;
|
|
; Abstract:
|
|
;
|
|
; CopyMem function
|
|
;
|
|
; Notes:
|
|
;
|
|
;------------------------------------------------------------------------------
|
|
|
|
DEFAULT REL
|
|
SECTION .text
|
|
|
|
;------------------------------------------------------------------------------
|
|
; VOID *
|
|
; EFIAPI
|
|
; InternalMemCopyMem (
|
|
; OUT VOID *DestinationBuffer,
|
|
; IN CONST VOID *SourceBuffer,
|
|
; IN UINTN Length
|
|
; );
|
|
;------------------------------------------------------------------------------
|
|
global ASM_PFX(InternalMemCopyMem)
|
|
ASM_PFX(InternalMemCopyMem):
|
|
push rsi
|
|
push rdi
|
|
mov rsi, rdx ; rsi <- Source
|
|
mov rdi, rcx ; rdi <- Destination
|
|
lea r9, [rsi + r8 - 1] ; r9 <- End of Source
|
|
cmp rsi, rdi
|
|
mov rax, rdi ; rax <- Destination as return value
|
|
jae .0
|
|
cmp r9, rdi
|
|
jae @CopyBackward ; Copy backward if overlapped
|
|
.0:
|
|
mov rcx, r8
|
|
and r8, 7
|
|
shr rcx, 3 ; rcx <- # of Qwords to copy
|
|
jz @CopyBytes
|
|
DB 0x49, 0xf, 0x7e, 0xc2 ; movd r10, mm0 (Save mm0 in r10)
|
|
.1:
|
|
DB 0xf, 0x6f, 0x6 ; movd mm0, [rsi]
|
|
DB 0xf, 0xe7, 0x7 ; movntq [rdi], mm0
|
|
add rsi, 8
|
|
add rdi, 8
|
|
loop .1
|
|
mfence
|
|
DB 0x49, 0xf, 0x6e, 0xc2 ; movd mm0, r10 (Restore mm0)
|
|
jmp @CopyBytes
|
|
@CopyBackward:
|
|
mov rsi, r9 ; rsi <- End of Source
|
|
lea rdi, [rdi + r8 - 1] ; rdi <- End of Destination
|
|
std ; set direction flag
|
|
@CopyBytes:
|
|
mov rcx, r8
|
|
rep movsb ; Copy bytes backward
|
|
cld
|
|
pop rdi
|
|
pop rsi
|
|
ret
|
|
|