04af8bf262
CorebootModulePkg and CorebootPayloadPkg originally supports coreboot only. In order to support other bootloaders, such as Slim Bootloader, they need be updated to be more generic. UEFI Payload (UefiPayloadPkg) a converged package from CorebootModulePkg and CorebootPayloadPkg with following updates: a. Support both coreboot and Slim Bootloader b. Removed SataControllerDxe and BaseSerialPortLib16550 to use EDK2 modules c. Support passing bootloader parameter to UEFI payload, e.g. coreboot table from coreboot or HOB list from Slim Bootloader d. Using GraphicsOutputDxe from EDK2 with minor change instead of FbGop e. Remove the dependency to IntelFrameworkPkg and IntelFrameworkModulePkg and QuarkSocPkg f. Use BaseDebugLibSerialPort library as DebugLib g. Use HPET timer, drop legacy 8254 timer support h. Use BaseXApicX2ApicLib instead of BaseXApicLib i. Remove HOB gUefiFrameBufferInfoGuid to use EDK2 graphics HOBs. j. Other clean ups On how UefiPayloadPkg could work with coreboot/Slim Bootloader, please refer UefiPayloadPkg/BuildAndIntegrationInstructions.txt Once UefiPayloadPkg is checked-in, CorebootModulePkg and CorebootPayloadPkg could be retired. Signed-off-by: Guo Dong <guo.dong@intel.com> Reviewed-by: Maurice Ma <maurice.ma@intel.com>
73 lines
2.1 KiB
NASM
73 lines
2.1 KiB
NASM
;------------------------------------------------------------------------------
|
|
;
|
|
; Copyright (c) 2015 - 2016, Intel Corporation. All rights reserved.<BR>
|
|
; SPDX-License-Identifier: BSD-2-Clause-Patent
|
|
;
|
|
; Abstract:
|
|
;
|
|
; Switch the stack from temporary memory to permanent memory.
|
|
;
|
|
;------------------------------------------------------------------------------
|
|
|
|
SECTION .text
|
|
|
|
;------------------------------------------------------------------------------
|
|
; VOID
|
|
; EFIAPI
|
|
; SecSwitchStack (
|
|
; UINT32 TemporaryMemoryBase,
|
|
; UINT32 PermenentMemoryBase
|
|
; );
|
|
;------------------------------------------------------------------------------
|
|
global ASM_PFX(SecSwitchStack)
|
|
ASM_PFX(SecSwitchStack):
|
|
;
|
|
; Save three register: eax, ebx, ecx
|
|
;
|
|
push eax
|
|
push ebx
|
|
push ecx
|
|
push edx
|
|
|
|
;
|
|
; !!CAUTION!! this function address's is pushed into stack after
|
|
; migration of whole temporary memory, so need save it to permanent
|
|
; memory at first!
|
|
;
|
|
|
|
mov ebx, [esp + 20] ; Save the first parameter
|
|
mov ecx, [esp + 24] ; Save the second parameter
|
|
|
|
;
|
|
; Save this function's return address into permanent memory at first.
|
|
; Then, Fixup the esp point to permanent memory
|
|
;
|
|
mov eax, esp
|
|
sub eax, ebx
|
|
add eax, ecx
|
|
mov edx, [esp] ; copy pushed register's value to permanent memory
|
|
mov [eax], edx
|
|
mov edx, [esp + 4]
|
|
mov [eax + 4], edx
|
|
mov edx, [esp + 8]
|
|
mov [eax + 8], edx
|
|
mov edx, [esp + 12]
|
|
mov [eax + 12], edx
|
|
mov edx, [esp + 16] ; Update return address into permanent memory
|
|
mov [eax + 16], edx
|
|
mov esp, eax ; From now, esp is pointed to permanent memory
|
|
|
|
;
|
|
; Fixup the ebp point to permanent memory
|
|
;
|
|
mov eax, ebp
|
|
sub eax, ebx
|
|
add eax, ecx
|
|
mov ebp, eax ; From now, ebp is pointed to permanent memory
|
|
|
|
pop edx
|
|
pop ecx
|
|
pop ebx
|
|
pop eax
|
|
ret
|