fce4ecd92c
Initial coreboot UEFI payload code check in. It provides UEFI services on top of coreboot that allows UEFI OS boot. CorebootModulePkg is the source code package of coreboot support modules that will be used to parse the coreboot tables and report memory/io resources. It supports the following features: - Support Unified Extensible Firmware Interface (UEFI) specification 2.4. - Support Platform Initialization(PI) specification 1.3. - Support execution as a coreboot payload. - Support USB 3.0 - Support SATA/ATA devices. - Support EFI aware OS boot. The following features are not supported currently and have not been validated: - GCC Tool Chains - SMM Execution Environment - Security Boot It was tested on a Intel Bay Trail CRB platform. Contributed-under: TianoCore Contribution Agreement 1.0 Signed-off-by: Maurice Ma <maurice.ma@intel.com> Reviewed-by: Prince Agyeman <prince.agyeman@intel.com> git-svn-id: https://svn.code.sf.net/p/edk2/code/trunk/edk2@17084 6f19259b-4bc3-4df7-8a09-765794883524
79 lines
2.4 KiB
ArmAsm
79 lines
2.4 KiB
ArmAsm
#------------------------------------------------------------------------------
|
|
#
|
|
# Copyright (c) 2013, Intel Corporation. All rights reserved.<BR>
|
|
# This program and the accompanying materials
|
|
# are licensed and made available under the terms and conditions of the BSD License
|
|
# which accompanies this distribution. The full text of the license may be found at
|
|
# http://opensource.org/licenses/bsd-license.php.
|
|
#
|
|
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
|
|
#
|
|
# Abstract:
|
|
#
|
|
# Switch the stack from temporary memory to permenent memory.
|
|
#
|
|
#------------------------------------------------------------------------------
|
|
|
|
|
|
#------------------------------------------------------------------------------
|
|
# VOID
|
|
# EFIAPI
|
|
# SecSwitchStack (
|
|
# UINT32 TemporaryMemoryBase,
|
|
# UINT32 PermenentMemoryBase
|
|
# )#
|
|
#------------------------------------------------------------------------------
|
|
ASM_GLOBAL ASM_PFX (SecSwitchStack)
|
|
ASM_PFX(SecSwitchStack):
|
|
#
|
|
# Save standard registers so they can be used to change stack
|
|
#
|
|
pushl %eax
|
|
pushl %ebx
|
|
pushl %ecx
|
|
pushl %edx
|
|
|
|
#
|
|
# !!CAUTION!! this function address's is pushed into stack after
|
|
# migration of whole temporary memory, so need save it to permenent
|
|
# memory at first!
|
|
#
|
|
movl 20(%esp), %ebx # Save the first parameter
|
|
movl 24(%esp), %ecx # Save the second parameter
|
|
|
|
#
|
|
# Save this function's return address into permenent memory at first.
|
|
# Then, Fixup the esp point to permenent memory
|
|
#
|
|
movl %esp, %eax
|
|
subl %ebx, %eax
|
|
addl %ecx, %eax
|
|
movl 0(%esp), %edx # copy pushed register's value to permenent memory
|
|
movl %edx, 0(%eax)
|
|
movl 4(%esp), %edx
|
|
movl %edx, 4(%eax)
|
|
movl 8(%esp), %edx
|
|
movl %edx, 8(%eax)
|
|
movl 12(%esp), %edx
|
|
movl %edx, 12(%eax)
|
|
movl 16(%esp), %edx # Update this function's return address into permenent memory
|
|
movl %edx, 16(%eax)
|
|
movl %eax, %esp # From now, esp is pointed to permenent memory
|
|
|
|
#
|
|
# Fixup the ebp point to permenent memory
|
|
#
|
|
movl %ebp, %eax
|
|
subl %ebx, %eax
|
|
addl %ecx, %eax
|
|
movl %eax, %ebp # From now, ebp is pointed to permenent memory
|
|
|
|
popl %edx
|
|
popl %ecx
|
|
popl %ebx
|
|
popl %eax
|
|
ret
|
|
|
|
|