cf1d454983
Add FSP2.0 support. This series of patch is to support FSP2.0 specification at https://firmware.intel.com/sites/default/files/FSP_EAS_v2.0_Draft%20External.pdf Some major updates include: 1) One FSP binary is separated to multiple components: FSP-T, FSP-M, FSP-S, and optional FSP-O. Each component has its own configuration data region. 2) All FSP-APIs use same UPD format - FSP_UPD_HEADER. 3) Add EnumInitPhaseEndOfFirmware notifyphase. 4) FSP1.1/FSP1.0 compatibility is NOT maintained. 5) We also add rename Fsp* to FspWrapper* in IntelFsp2WrapperPkg, to indicate that it is for FspWrapper only. IntelFspPkg and IntelFspWrapperPkg will be deprecated. The new Intel platform will follow FSP2.0 and use IntelFsp2Pkg and IntelFsp2WrapperPkg. The old platform can still use IntelFspPkg and IntelFspWrapperPkg for compatibility consideration. Cc: Giri P Mudusuru <giri.p.mudusuru@intel.com> Cc: Maurice Ma <maurice.ma@intel.com> Cc: Ravi P Rangarajan <ravi.p.rangarajan@intel.com> Contributed-under: TianoCore Contribution Agreement 1.0 Signed-off-by: Jiewen Yao <jiewen.yao@intel.com> Reviewed-by: Giri P Mudusuru <giri.p.mudusuru@intel.com> Reviewed-by: Maurice Ma <maurice.ma@intel.com> Reviewed-by: Ravi P Rangarajan <ravi.p.rangarajan@intel.com>
79 lines
2.5 KiB
NASM
79 lines
2.5 KiB
NASM
;------------------------------------------------------------------------------
|
|
;
|
|
; Copyright (c) 2015, Intel Corporation. All rights reserved.<BR>
|
|
; This program and the accompanying materials
|
|
; are licensed and made available under the terms and conditions of the BSD License
|
|
; which accompanies this distribution. The full text of the license may be found at
|
|
; http://opensource.org/licenses/bsd-license.php.
|
|
;
|
|
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
|
|
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
|
|
;
|
|
; Abstract:
|
|
;
|
|
; Switch the stack from temporary memory to permanent memory.
|
|
;
|
|
;------------------------------------------------------------------------------
|
|
|
|
SECTION .text
|
|
|
|
;------------------------------------------------------------------------------
|
|
; VOID
|
|
; EFIAPI
|
|
; SecSwitchStack (
|
|
; UINT32 TemporaryMemoryBase,
|
|
; UINT32 PermenentMemoryBase
|
|
; );
|
|
;------------------------------------------------------------------------------
|
|
global ASM_PFX(SecSwitchStack)
|
|
ASM_PFX(SecSwitchStack):
|
|
;
|
|
; Save three register: eax, ebx, ecx
|
|
;
|
|
push eax
|
|
push ebx
|
|
push ecx
|
|
push edx
|
|
|
|
;
|
|
; !!CAUTION!! this function address's is pushed into stack after
|
|
; migration of whole temporary memory, so need save it to permanent
|
|
; memory at first!
|
|
;
|
|
|
|
mov ebx, [esp + 20] ; Save the first parameter
|
|
mov ecx, [esp + 24] ; Save the second parameter
|
|
|
|
;
|
|
; Save this function's return address into permanent memory at first.
|
|
; Then, Fixup the esp point to permanent memory
|
|
;
|
|
mov eax, esp
|
|
sub eax, ebx
|
|
add eax, ecx
|
|
mov edx, dword [esp] ; copy pushed register's value to permanent memory
|
|
mov dword [eax], edx
|
|
mov edx, dword [esp + 4]
|
|
mov dword [eax + 4], edx
|
|
mov edx, dword [esp + 8]
|
|
mov dword [eax + 8], edx
|
|
mov edx, dword [esp + 12]
|
|
mov dword [eax + 12], edx
|
|
mov edx, dword [esp + 16] ; Update this function's return address into permanent memory
|
|
mov dword [eax + 16], edx
|
|
mov esp, eax ; From now, esp is pointed to permanent memory
|
|
|
|
;
|
|
; Fixup the ebp point to permenent memory
|
|
;
|
|
mov eax, ebp
|
|
sub eax, ebx
|
|
add eax, ecx
|
|
mov ebp, eax ; From now, ebp is pointed to permanent memory
|
|
|
|
pop edx
|
|
pop ecx
|
|
pop ebx
|
|
pop eax
|
|
ret
|